Requiem for Relativity

By the way, we do not make up things like the electron and the proton. There really is something there. We can actually touch them. And when we do it HURTS! Sometimes enough to kill.

But we <u>do</u> make up the models we use to think about them and talk about them. I suspect that it is these models, and in particular our models of the electron rather than the electron itself, that you are complaining about.

LB

Jim,

Models are obviously not perfect. And that lack of perfection can lead to frustration. But the real world is very big and complicated and in order to think about it and talk about it we we have to break it down into 'bite sized' chunks that are intended to be less complex. We call them models. Or theories. Or guesses. Or ideas. (If our frustration becomes large enough, we have more names for them ...)

And then we live with them and their imperfections. Until we can come up with something better.

Of course, sometimes the new better thing is not really better.

Sigh.

LB

What follows is a sequence of five emails to fellow scientists, about my recent work analyzing Dayton Miller's ether drift data.


July 11, 2013:

Dear Thomas (Goodey)(cc: Pierre Fuerxer who also responded to my group email),

Great quote from Kipling about the unforgiving nature of machines; we see a lot of farm machinery injuries around here, not so much as in the past mainly because there is less child labor, but still a lot.

Also, I was able to download your map of the drift vectors and the possibly related astronomical vectors, no problem with either the attachment or the backup attachment. Well done map! Great to have such a clearly laid out map with the precise numerical data in an inset table. While it is eye catching that Miller's Mt. Wilson vector is so much closer to the normal to Luna's orbit normal vector than to anything else, still there was little correlation between the change in Miller's Mt. Wilson drift vector at his four epochs, and the change in Luna's orbit normal vector. And to be significant at the 1% level without any such correlation, Miller's drift vector would have to be 10x closer to Luna's orbit normal vector than to, say, the normal to the invariant plane. Of course many things are not statistically significant, yet are true.

I lost the data file part of my program (floppy disk and hard drive both went bad over the years) but I remembered enough to rewrite the whole program with convenient included DATA statements and explanatory REM statements, and just finished today. The program's mathematical analysis is much more competent than what I did in 2004. It includes Miller's Cleveland experiments (all with the steel interferometer) 1922-1924. I haven't had time to input the data from Miller's 1927-1929 Cleveland work or the small amount of somewhat difficult to redact work notes that he did with Morley with the steel interferometer in Cleveland in 1905. I hope to email the whole program to you and Pierre next time I get to the university and can get to a computer with a floppy drive & good email & document processing hookup.

One thing I am finding that I didn't quite wrap my brain around back in 2004 when I did this: it seems that the positive correlation of "longer telescope arm path" with a direction roughly toward the poles of the ecliptic, is merely a mathematical byproduct of a stronger correlation, a negative one. This negative correlation is roughly parallel to the CMB dipole, i.e. the alleged cosmic motion of the Sun. It is as if, yes, the wavetrain contracts so there are more waves per micron, but also the interferometer contracts more than the wavetrain. After all, the electron shell matter of the interferometer is essentially a wavetrain itself, though of shorter wavelength. However it is not Fitzgerald contraction in which the interferometer arm and the light wavetrain contract perfectly equally (i.e. "space contraction" relativistic baloney). It is a dispersion phenomenon in which the interferometer arm contracts slightly more, hence the correlation with the fringe shifts is negative, not positive as Maxwell, Michelson & Miller expected. I did write about this on the messageboard of www.metaresearch.org (the website of the late Dr. Van Flandern) several years ago.

My results "hot off the presses" today (this email is my first announcement to anyone):

Best fitting constant space direction of ether drift:

RA 40, Decl +10 (from hemispheric search to nearest 5 degrees) (or equivalently RA 220, Decl -10)

correlation coefficient between observed and expected second harmonic coefficients is -0.4005 (yes, negative)
approximating sigma = -4.74 standard deviation units of significance

Among directions giving a positive correlation, the best is

RA 210, Decl +65

but the correlation coeff is merely +0.3435, sigma = +4.00

These data comprise 64 of what Miller called "experiments", each on one page of the notebook, typically comprising 10 to 20 turns of the interferometer (some 1923 experiments were excluded because they were Miller's test of a heat lamp effect which clearly swamped everything else). The correlation coefficient is for 64*2 = 128 items because of the cos(2*theta) and sin(2*theta) coefficients.

Sigma = 4.00 is highly significant but sigma = 4.74 is much more so.

Would you please forward this to Jim DeMeo? Without him we would be nowhere on this, but I misplaced his email address and this library is closing.

- Joe Keller


July 12, 2013:

To: Thomas Goodey, Pierre Fuerxer, James DeMeo

Dear sirs:

This is the BASIC program I spoke of yesterday. With the help of the student at the computer help center at Iowa State University (just down the hall from where Thomas and I worked together that long ago February night in 2004) I was able to cut and paste it about half a page at a time from the BASIC language command prompt window into an email to myself, then remove the myriad unwanted headers and word processing characters that had been inserted. It was almost as much work as retyping the program. I've checked it hastily but can't guarantee that there are no errors from this copying process. For that matter, I haven't had time to double check my data entry and can't guarantee that there are no errors there, either. Remarkably, in 2004 I found several column sum errors on Miller's notebook pages, almost all of them very small, marked those on my copies of the pages, rechecked those errors during these last few days and found that I had been correct in every case.

To reiterate and add to what was in my email yesterday, this program analyzes only what I analyzed in 2004, namely Miller's 1922-1924 steel interferometer experiments in Cleveland. I intend to augment the data to include the similar 1927-1929 experiments, which also were by Miller with the steel interferometer in Cleveland.

The program determined that if restricted to positive correlation coefficients (i.e. sign of fringe shift what was expected by Maxwell, Michelson & Miller) the best is

RA 210, Decl +65

and the correlation coeff is +0.3435, sigma = +4.00

but my best fitting constant space direction of ether drift is:

RA 40, Decl +10 (from hemispheric search to nearest 5 degrees) (or equivalently RA 220, Decl -10)

correlation coefficient between observed and expected second harmonic coefficients is -0.4005 (yes, negative)
approximating sigma = -4.74 standard deviation units of significance.

Sigma = 4.00 is highly significant but sigma = 4.74 is much more so.



So, the apparent ether drift in a direction approximating perpendicular to the ecliptic, seems to be merely a mathematical byproduct of the main effect, which is an ether drift roughly approximating parallel or antiparallel to the CMB dipole. This makes the ether drift much more credible.



Not only the negative sign, but also the small magnitude (I find about the same magnitudes Miller did) can be explained as a dispersion phenomenon: the speed of light at visible light frequency is higher than at frequencies comparable to the electron waves in the atoms of the steel arm. So, it amounts to an overcompensating FitzGerald contraction, not any distortion of space itself.



- Joe Keller

---

From: josephkeller100@hotmail.com
To: josephkeller100@hotmail.com; josephckeller@gmail.com
Subject: program pasted from commmand prompt
Date: Fri, 12 Jul 2013 15:47:44 -0500

&lt;!-- .ExternalClass .ecxhmmessage P { padding:0px; } .ExternalClass body.ecxhmmessage { font-size:12pt; font-family:Calibri; } --&gt;

REM Program name "DMCLEV.BAS", by Joseph C. Keller, Roland Iowa May 2004
REM Redone by JC Keller June 30 - July 2013 because "text" data file lost.
REM The new program is much more capable than the old.
REM The program is written in BASIC, Microsoft "QBASIC" circa 1993 vintage
REM and runs on a 1993 vintage Intel 486 (pre-Pentium) IBM computer.
REM "There's never enough time to do it right, but there's always enough time
REM to do it over." - Jack Bergman writing in a book of humor
REM DATA lines are Dayton Miller's Cleveland data from 1922-1923:
REM in Goodey-Keller page numbering of Miller notebook
REM (obtained by James DeMeo from the Case Archives) pp. 0083-0135.
REM Goodey & Keller numbered the pages, working with the assistance
REM of hired students in the lobby of the
REM Iowa State Univ. Memorial Union, Feb. 2004 at Goodey's suggestion.
REM pp. 0083-0095 titled "Cleveland, Ohio April, 1922"
REM subtitled "5 sets, 71 turns"

REM & pp. 0095-0135 titled "Cleveland, Ohio Aug 23-Sep 4, 1923"
REM subtitled "39 sets, 477 turns" though I use only [18 sets, 263 turns]
REM & omit 21 of these 39 because they were tests of the
REM effect of heater(s) (or "three electric bulbs" on p=119) in the room.
REM In 1923 the 18 2nd harmonic displacements calculated by Miller for the
REM experiments without heaters were
REM 6,8,18,9,17,18,12,4,8,8,10,6,4,4,4,10,3,5
REM & the 21 with heaters were
REM 97,77,10,73,122,118,31,77,85,135,54,12,22,14,78,61,19,22,42,83,72
REM where the smaller heater effects were correlated with thermal shielding.
REM So the heater effect swamped all other effects and those experiments
REM must be omitted.

REM & pp. 0136-0179 titled "Cleveland, Ohio June 27-July 26, 1924"
REM subtitled "42 sets, 598 turns"; I use [41 seets, 587 turns] because
REM p=156 is missing a column


REM Miller's Index, p. 005, lists other epochs for which there were
REM steel interferometer data at Cleveland; I confirmed these as
REM present in the notebook, though it is mostly devoted to Mt. Wilson data
REM (not only the Mar-Apr 1925, Jul-Aug 1925, Sep 1925 & Feb 1926 epochs
REM discussed in Miller's Physical Review article, but also considerable
REM Apr 1921 & Sep 1924 epochs with the steel interferometer @ Mt. Wilson)
REM (1905 are Morley-Miller)
REM July 1905 (48 turns, p. 041)
REM Oct 1905 (127 turns, pp. 038-040)
REM Nov 1905 (55 turns, p. 042)
REM Apr 1927 (20, 400 turns)
REM Aug 1927 (41, 820 turns)
REM Sep-Oct 1929 (11 sets, 220 turns)(Cleveland 1927 & 1929 are pp. 977-1054)

REM Program finds best fit ether drift vector in space
REM A few pages are cut off, requiring a little guesswork about exact times;
REM I'll note this as arises.

REM setting constants

REM setting numerical constants
PRINT : PRINT : pi# = ATN(1) * 4: pi180# = pi# / 180
REM sum of squares of 1-9, 2-9,...,16-9
jv0# = 1496 - 2 * 9 * 136 + 16 * 9 ^ 2

REM setting astronomical constants
REM tropical yr 1960 from Newcomb linear formula cited by Clemence 1946
yr# = 365.242195#: yrinv# = 1 / yr#
REM Julian date of 0h Jan 1 1992
jd0# = 2448622.5#
REM JD of J2000.0 i.e. 12h Jan 1 2000
jd00# = 2451545

REM setting geographic constants
REM estimated geographic latitude & longitude of Miller's lab at Case
latcase# = 41.5056# * pi180#: longcase# = 81.6083# * pi180#
cscase# = COS(latcase#): sncase# = SIN(latcase#)
REM The location in Cleveland 1922-1924 was the "Physical Laboratory",
REM (presumably not the temporary building used by Morley & Miller in 1905 -
REM which was at 285 m alt in East Cleveland).
REM The "Physical Laboratory" would have been on the main campus therefore
REM about 41 deg 31' lat and 81 deg 33'30" long
REM In 1927 the interferometer was moved from Mt. Wilson to the Case campus
REM about 690 ft alt, 41 deg 30'20" lat and 81 deg 36'30" long
REM so these coordinates will be assumed for 1922-1924 & 1927-1929
REM at the risk of a 3' longitude error for 1922-1924.

REM physical and time constants
REM speed of light in km/s
clight# = 2.997925# * 10 ^ 5
REM number of lightwaves in usual interferometer path according to Miller
nwv# = 112 * 10 ^ 6
REM Greenwich sidereal time in radians
REM for 0h GMT Jan 1 1992 per 1992 World Almanac
REM given to nearest 0.1sec = 1.5"
stime0# = (1 * 15 + 6 / 4 + 39.6# / 240) * pi180#

REM dimensioning variables
DIM shift(200, 27) AS DOUBLE: DIM c(17) AS DOUBLE: DIM s(17) AS DOUBLE
DIM sh(200, 2) AS DOUBLE

REM read, standardize and Fourier analyze Miller's data
REM using Miller's column sums
GOSUB 9000
REM find correlation with Fourier components expected for each of a
REM grid of ether drift directions on the J2000 celestial sphere
GOSUB 7000
REM print results
GOSUB 5000

END


REM find cross product v1 cross v2 = v3
1000
x3# = y1# * z2# - z1# * y2#
y3# = z1# * x2# - x1# * z2#
z3# = x1# * y2# - y1# * x2#
RETURN

5000 PRINT "The constant ether drift directions giving the largest "
PRINT "correlation coefficients, in absolute value, between "
PRINT "the expected (Maxwell ether drift theory) and "
PRINT "observed (according to column sums of Miller Cleveland experiments) "
PRINT "second harmonic coefficients of the fringe shifts, are "
PRINT "in J2000 celestial coordinates:"
PRINT "RA, Declination, corr coeff, sigma"
PRINT : PRINT lat1; " "; lon1; " "; cc1#,
PRINT .5# * LOG((1 + cc1#) / (1 - cc1#)) * SQR(nn - 3)
PRINT : PRINT lat2; " "; lon2; " "; cc2#,
PRINT .5# * LOG((1 + cc2#) / (1 - cc2#)) * SQR(nn - 3)
PRINT : PRINT lat3; " "; lon3; " "; cc3#,
PRINT .5# * LOG((1 + cc3#) / (1 - cc3#)) * SQR(nn - 3)
PRINT "Estimated speeds 1,2,3 in ether, km/sec :"
PRINT speed1#, speed2#, speed3#
PRINT "Number of data pairs = number of experiments x 2, i.e. ";
PRINT nn
RETURN

REM search grid of ether drift directions on J2000 celestial sphere
7000 PRINT "Checking Declination ";
inc = 5: q = 0
sv# = 0: sy# = 0: cc1# = 0: cc2# = 0: cc3# = 0
lat1 = -1001: lat2 = -1002: lat3 = -1003: lon1 = 0: lon2 = 0: lon3 = 0
speed1# = 0: speed2# = 0: speed3# = 0
FOR lat = 0 TO 90 STEP 5
PRINT lat; " ";
IF lat = 60 THEN LET inc = 10
IF lat = 70 THEN LET inc = 15
IF lat = 80 THEN LET inc = 30
IF lat = 90 THEN LET inc = 360
decdrift0# = lat * pi180#
FOR lon = 0 TO 359 STEP inc
radrift0# = lon * pi180#: sw# = 0: su# = 0: sx# = 0
FOR I = 1 TO counter
IF q = 0 THEN GOSUB 7500
GOSUB 7600
x1# = shift(I, 22): y1# = shift(I, 23): z1# = shift(I, 24)
x3# = shift(I, 25): y3# = shift(I, 26): z3# = shift(I, 27)
h1# = xdrift# * x1# + ydrift# * y1# + zdrift# * z1#
h3# = xdrift# * x3# + ydrift# * y3# + zdrift# * z3#
REM expected column sum amplitude is
REM proportional to speed squared x no. of turns
magh# = (h1# ^ 2 + h3# ^ 2) * shift(I, 18)
REM ph# = arctan(h3# / h1#)
REM Use identity cos(2*(th-ph))=cos(2*th)*cos(2*ph)+sin(2*th)*sin(2*ph)
REM g1=cos(2*ph) & g3=sin(2*ph)

tn# = h3# / h1#: den# = 1 / (1 + tn# ^ 2)
g3# = 2 * tn# * den#: g1# = (1 - tn# ^ 2) * den#
REM Find quantities proportional to expected Fourier coeffs of fringe shifts
exps1# = magh# * g1#: exps3# = magh# * g3#
REM Find correlation coeff of these with actual fringe shifts
sx# = sx# + exps1# + exps3#
su# = su# + exps1# ^ 2 + exps3# ^ 2
IF q = 0 THEN GOSUB 7700
sw# = sw# + exps1# * sh(I, 0) + exps3# * sh(I, 1)
NEXT I
q = 1
coa# = nn * sw#: cob# = sx# * sy#
coc# = nn * su#: cod# = sx# ^ 2
coe# = nn * sv#: cof# = sy# ^ 2
corrcoeff# = (coa# - cob#) / SQR((coc# - cod#) * (coe# - cof#))
GOSUB 7800
NEXT lon: NEXT lat
RETURN


REM subroutine to find vert. (unit normal to reference spheroid) at Cleveland
REM in celestial RA & Dec & xyz coords (v2 vector) of the equinox of date
REM & then north (v1) & east (v3) unit ground vectors
7500 jd# = shift(I, 17): t# = (jd# - jd0#) * (1 + yrinv#)
raclev# = t# * 2 * pi# + stime0# - longcase#
REM for those with times cut off and guessed,
REM will improve it by changing to Miller's written sidereal time
IF p = 90 THEN LET raclev# = (4 * 15 + 25 / 4) * pi180#
z2# = sncase#: x2# = COS(raclev#) * cscase#: y2# = SIN(raclev#) * cscase#
ra1# = raclev# + pi#: z1# = cscase#
x1# = COS(ra1#) * sncase#: y1# = SIN(ra1#) * sncase#
GOSUB 1000
shift(I, 22) = x1#: shift(I, 23) = y1#: shift(I, 24) = z1#
shift(I, 25) = x3#: shift(I, 26) = y3#: shift(I, 27) = z3#
RETURN

REM subroutine to find trial ether drift vector in coords of equinox of date

REM per "rigorous" formula in 1990 Astronomical Almanac
7600 jd# = shift(I, 17): t# = (jd# - jd00#) / 36525
zetaa# = .64062# * t# + 8 / 10 ^ 5 * t# ^ 2
za# = zetaa# + 22 / 10 ^ 5# * t# ^ 2
tha# = .55675# * t# - 12 / 10 ^ 5 * t# ^ 2 - 1 / 10 ^ 5 * t# ^ 3
sn# = COS(radrift0# + zetaa#) * SIN(tha#) * COS(decdrift0#)
sn# = sn# + COS(tha#) * SIN(decdrift0#)
cs# = SQR(1 - sn# ^ 2): decdrift# = ATN(sn# / cs#)
sn# = SIN(radrift0# + zetaa#) * COS(decdrift0#) / COS(decdrift#)
cs# = COS(radrift0# + zetaa#) * COS(tha#) * COS(decdrift0#)
cs# = (cs# - SIN(tha#) * SIN(decdrift0#)) / COS(decdrift#)
radrift# = ATN(sn# / cs#)
IF radrift# &lt; 0 THEN LET radrift# = radrift# + pi#
IF radrift0# - radrift# &gt; .1 THEN LET radrift# = radrift# + pi#
zdrift# = SIN(decdrift#): cs# = COS(decdrift#)
xdrift# = COS(radrift#) * cs#
ydrift# = SIN(radrift#) * cs#
RETURN


REM For first drift vector only, find actual shift sums for corr coeff calc
7700 sy# = sy# + sh(I, 0) + sh(I, 1)
sv# = sv# + sh(I, 0) ^ 2 + sh(I, 1) ^ 2
RETURN

REM save largest, or most positive, three correlation coeffs
7800 cc# = corrcoeff#
REM GOTO 7806
REM find largest correlation coeff of either sign
IF ABS(cc#) &gt; ABS(cc1#) THEN GOTO 7810
IF ABS(cc#) &gt; ABS(cc2#) THEN GOTO 7820
IF ABS(cc#) &gt; ABS(cc3#) THEN GOTO 7830
RETURN

REM find most positive correlation coeff
7806 IF cc# &gt; cc1# THEN GOTO 7810
IF cc# &gt; cc2# THEN GOTO 7820

IF cc# &gt; cc3# THEN GOTO 7830
7808 RETURN

7810 cc3# = cc2#: cc2# = cc1#: cc1# = cc#
lat3 = lat2: lon3 = lon2: lat2 = lat1: lon2 = lon1: lat1 = lat: lon1 = lon
GOSUB 7850
speed3# = speed2#: speed2# = speed1#: speed1# = speed#
GOTO 7808

7820 cc3# = cc2: cc2# = cc#
lat3 = lat2: lon3 = lon2: lat2 = lat: lon2 = lon
GOSUB 7850
speed3# = speed2#: speed2# = speed#
GOTO 7808

7830 cc3# = cc#
lat3 = lat: lon3 = lon
GOSUB 7850

speed3# = speed#
GOTO 7808

REM The best-fit slope is the best-fit 2nd harmonic amplitude
REM that would occur if the
REM velocity vector were such that Maxwell would predict amplitude = 1
REM ("1" = 0.1 wavelength in Miller's data recording shorthand)
REM so the equation is
REM 1/4*(v/c)^2*nwv*10 = slope
7850
speed# = clight# * SQR(ABS((coa# - cob#) / (coc# - cod#)) * 4 / nwv# / 10)
RETURN

REM Read, standardize, and Fourier analyze data
REM c(j) & s(j) are coeffs to convolve fringe shifts
REM with cos & sin(2*azimuth), resp.
9000 rt2inv# = 1 / SQR(2): c(1) = 1: c(9) = 1: s(3) = 1: s(11) = 1
c(5) = -1: c(13) = -1: s(9) = -1: s(1) = -1

c(3) = 0: c(11) = 0: c(7) = 0: c(15) = 0
s(7) = 0: s(15) = 0: s(11) = 0: s(3) = 0: c(17) = c(1): s(17) = s(1)
FOR I = 2 TO 16 STEP 2
c(I) = (c(I - 1) + c(I + 1)) * rt2inv#
s(I) = (s(I - 1) + s(I + 1)) * rt2inv#
NEXT I
counter = 0
FOR I = 1 TO 200
READ y, mo, d, hr, min, n, p
IF n = 0 THEN GOTO 9090
IF y &lt; 1922 OR y &gt; 1924 THEN PRINT "?! data error"
counter = counter + 1
IF y = 1922 THEN LET jd# = jd0# - 70 * 365 - 17
IF y = 1923 THEN LET jd# = jd0# - 69 * 365 - 17
IF y = 1924 THEN LET jd# = jd0# - 68 * 365 - 17
IF mo = 4 THEN LET jd# = jd# + 90
IF mo = 6 THEN LET jd# = jd# + 151
IF mo = 7 THEN LET jd# = jd# + 181
IF mo = 8 THEN LET jd# = jd# + 212
IF mo = 9 THEN LET jd# = jd# + 243
IF y = 1924 AND mo &gt; 2 THEN LET jd# = jd# + 1
REM p=89 & p=91 reveal that turn rate was about 40 turns/35 min
REM so if one time is given it likely was the start rather than midpoint
IF p = 89 OR p = 91 OR p = 177 THEN GOTO 9010
jd# = jd# + n / 2 * 35 / 40 / 1440
GOTO 9020
9010 IF p = 89 THEN LET jd# = jd# + 25 / 2 / 1440
IF p = 91 THEN LET jd# = jd# + 10 / 2 / 1440
IF p = 177 THEN LET jd# = jd# + 45 / 2 / 1440
9020 shift(I, 17) = jd# + d - 1 + hr / 24 + min / 1440
shift(I, 18) = n: shift(I, 19) = p: js = 0
FOR j = 1 TO 16
READ jx
REM (+) fringe shift is that which would occur with longer telescope arm.
REM Use of only half the mirrors reverses the sign of the expected shift??
REM IF p &lt; 91 THEN LET jx = -jx
REM p=86,88 explicitly & p=89,90 implicitly used only half usual pathlength;
REM will correct for this:
IF p &lt; 91 THEN LET jx = jx * 2
REM p=90 has top of copy cut off; p=89 or p=90 might need doubling.
REM p=91 explicitly used usual ("16 reflections") pathlength.
js = js + jx: shift(I, j) = jx
NEXT j
jm = js / 16
REM reduce to zero mean
FOR j = 1 TO 16
shift(I, j) = shift(I, j) - jm
NEXT j
REM detrend using best fit line
REM ju = 0
jw = 0
FOR j = 1 TO 16
REM ju = ju + shift(i, j) ^ 2
jw = jw + shift(I, j) * (j - 9)
NEXT j
REM Best fit line is through (0,0) & has slope equal to
REM correlation coefficient * std deviation of ordinate / std dev abscissa
REM slope# = jw / SQR(ju * jv0#) * SQR(ju / jv0#)
slope# = jw / jv0#
FOR j = 1 TO 16
shift(I, j) = shift(I, j) - slope# * (j - 9)
NEXT j
NEXT I
9090 nn = counter * 2
PRINT "Miller's column sum data have been read and standardized."
PRINT "nn = "; nn
GOSUB 9100
RETURN

REM Fourier analyze data
9100 FOR I = 1 TO counter
sc# = 0: ss# = 0
FOR j = 1 TO 16
sc# = sc# + shift(I, j) * c(j)
ss# = ss# + shift(I, j) * s(j)
NEXT j
shift(I, 20) = sc# / 16 / (1 / 2): shift(I, 21) = ss# / 8
REM redundant variable below is to enhance array access speed
sh(I, 0) = shift(I, 20): sh(I, 1) = shift(I, 21)
NEXT I
PRINT "Miller's data have been Fourier analyzed."
RETURN


REM Format of data:
REM time of each turning session in yr,mo,d,hr,min (Eastern Std. Time)
REM n = number of turns of interferometer
REM p = experiment's Goodey-Keller pagination number in Miller's notebook
REM I use Miller's non-detrended column sums,
REM omitting the last column
REM which is redundant except for its bottom entry.
REM Rather than use Miller's detrending, I'll detrend using a best-fit line
REM for each experiment page.

REM 1922 data
DATA 1922,4,14,14,45,10,86
DATA 100,74,56,49,63,90,112,129,119,107,107,106,105,100,98,97
DATA 1922,4,17,14,25,6,88
DATA 42,38,38,42,44,48,60,69,70,63,56,50,52,61,62,64
DATA 1922,4,17,17,0,28,89
DATA 12,10,4,15,26,46,72,92,90,79,64,44,28,15,16,21
DATA 1922,4,18,16,30,25,90
REM for p=90, must guess civil time (page cut off) but will
REM replace with Miller's sidereal time
REM in subroutine getting sidereal times from JD's
DATA -243,-258,-302,-338,-367,-369,-333,-309,-305,-323,-323,-320,-296,-284,-265,-258
DATA 1922,4,19,15,50,12,91
DATA -9,-15,-8,12,42,52,47,52,52,75,112,136,132,107,60,20

REM 1923 data
DATA 1923,8,23,13,30,11,97
REM minor addition error in col. 11 corrected
DATA -31,-31,-28,-23,-22,-20,-22,-24,-30,-27,-24,-21,-17,-9,4,12
DATA 1923,8,24,16,45,12,98
DATA 42,47,52,56,56,58,52,47,47,48,55,51,48,45,47,48
DATA 1923,8,25,9,40,18,99
REM Miller notes "Increasing telescope arm increases reading."
REM This sentence also appears for p=100,101,103,104,106,108-112,118
REM & of 1923 experiments, only p=126 has (ambiguously) contrary statement.
DATA 4,18,40,55,59,56,39,20,12,10,18,26,28,21,14,12
DATA 1923,8,25,12,0,13,100
DATA 3,7,13,-18,20,20,10,3,6,5,9,16,14,19,21,23
DATA 1923,8,27,11,20,9,101
DATA -53,-47,-42,-30,-43,-54,-63,-71,-73,-73,-76,-78,-82,-91,-97,-90
REM on p=102, Miller notes "Heater placed at azimuth 4"
REM so this experiment is omitted
DATA 1923,8,27,15,10,6,103
DATA 19,24,28,31,30,21,19,18,20,22,20,18,13,11,11,17
DATA 1923,8,27,15,30,24,104
REM "Light shielded by cardboard"
REM Many experiments in this part say they had a little shielding of some sort
REM but only the most thoroughly shielded will be quoted.
DATA -215,-193,-176,-167,-168,-182,-198,-209,-214,-213,-212,-222,-235,-240,-238,-226
REM on p=105, Miller notes "Heater placed at Az. 2."
REM so this experiment is omitted also
DATA 1923,8,28,11,45,12,106
DATA -13,-10,-8,-6,0,-1,-4,-6,-8,-12,-10,-10,-12,-12,-11,-14
DATA 1923,8,28,14,20,16,107
REM "...interferometer shielded from heat by cardboard"
DATA -196,-192,-189,-191,-197,-206,-212,-212,-217,-214,-223,-212,-215,-215,-217,-212
DATA 1923,8,28,15,30,12,108
DATA 56,60,62,60,58,56,56,57,58,60,60,60,60,59,59,63
DATA 1923,8,29,9,0,11,109
DATA -39,-35,-37,-39,-37,-45,-45,-50,-49,-47,-44,-42,-39,-43,-46,-49
DATA 1923,8,30,9,30,22,110
DATA 69,77,82,80,82,83,82,77,81,84,88,86,84,83,84,93
DATA 1923,8,30,10,0,11,111
DATA 69,74,75,79,80,81,78,75,78,78,78,79,80,79,81,87
DATA 1923,8,30,10,30,22,112
DATA 17,24,24,24,21,23,19,17,18,21,18,15,14,15,17,20
DATA 1923,8,30,15,40,22,113
DATA 64,67,67,65,66,65,66,66,69,73,76,75,70,69,70,72
REM p=114-117 have "Heater"(s) & are omitted
DATA 1923,8,31,9,0,8,118
REM minor addition error in 4th col. corrected
DATA -29,-28,-30,-36,-38,-43,-44,-44,-40,-38,-38,-37,-34,-39,-41,-38
REM on p=119 Miller notes "3 electric bulbs at Az 4"
REM so though less powerful than a "heater", this experiment also omitted.
REM p=120-123 have "Heater"; will be omitted.
DATA 1923,9,1,9,30,20,124
REM Miller notes "Glass and steel of all arms covered."
REM minor sum error col. 1 corrected
DATA 214,214,214,213,213,211,208,208,213,215,216,214,211,207,207,209
REM p=125 has "Heater" and though "Glass and steel of all arms covered"
REM will be omitted.
REM p=126-134 have "Heater" & are omitted
DATA 1923,9,4,16,30,14,135
REM minor errors summing cols. 2-4 corrected
DATA 82,85,86,85,85,83,82,84,88,89,89,87,84,81,82,84

REM 1924 Cleveland data
DATA 1924,6,27,14,5,8,138
REM Miller notes "Increasing readings, +, always means
REM increased length of telescope arm"
REM sign of column 7 corrected
DATA 3,8,0,-2,6,10,14,9,-4,-8,-4,-15,-21,-27,-17,-23
DATA 1924,6,27,15,0,10,139
DATA -119,-117,-125,-126,-127,-129,-131,-131,-132,-129,-133,-135,-141,-147,-146,-139
DATA 1924,6,28,10,45,14,140
DATA -40,-42,-50,-54,-54,-54,-55,-56,-53,-58,-66,-75,-77,-76,-73,-69

DATA 1924,6,30,10,0,19,141
DATA -31,-26,-38,-47,-66,-68,-56,-58,-59,-64,-75,-93,-101,-92,-71,-57
DATA 1924,7,1,11,40,10,142
DATA -117,-109,-100,-111,-118,-120,-103,-108,-105,-115,-139,-150,-154,-155,-144,-134
DATA 1924,7,1,16,45,9,143
REM Miller's #46
DATA -2,-10,-14,-20,-22,-22,-21,-19,-14,-12,-14,-18,-20,-21,-14,-12
DATA 1924,7,1,12,0,10,144
REM Miller's #45
DATA 35,48,52,51,37,40,48,55,55,45,24,8,2,3,8,19
DATA 1924,7,5,8,40,12,145
REM top of page cut off; time deduced by comparing with other sidereal times
DATA 104,99,86,74,64,88,117,125,117,111,101,98,95,106,121,137
DATA 1924,7,5,9,39,11,146
REM as for p=145
DATA 86,85,77,67,72,72,84,99,108,102,89,80,70,74,79,88
DATA 1924,7,5,10,10,12,147
DATA -132,-128,-121,-125,-136,-138,-126,-127,-118,-123,-138,-140,-151,-148,-149,-150
DATA 1924,7,5,11,45,10,148
DATA -94,-96,-99,-102,-107,-108,-105,-96,-96,-98,-105,-111,-116,-120,-116,-111
DATA 1924,7,7,10,45,10,149
DATA 18,19,19,17,17,16,17,20,17,17,14,11,10,10,13,19
DATA 1924,7,7,11,40,20,150
DATA -151,-149,-145,-143,-142,-142,-140,-137,-142,-146,-157,-167,-195,-180,-173
DATA 1924,7,7,14,30,20,151
DATA 18,25,32,38,37,34,33,31,29,23,19,11,4,0,14,27
DATA 1924,7,7,14,45,20,152
DATA -109,-105,-103,-103,-105,-107,-102,-100,-99,-104,-112,-12,-127,-129,-121,-112
REM minor addition error 1st col. corrected
DATA 61,55,48,40,40,37,44,47,52,50,50,39,36,35,55,76
DATA 1924,7,8,22,30,14,158
DATA 27,22,19,15,12,11,9,13,17,19,16,9,9,10,18,32
DATA 1924,7,9,9,0,20,159
DATA 168,170,173,167,162,155,156,161,165,167,174,178,172,174,175,189
DATA 1924,7,9,14,25,10,160
DATA -55,-57,-56,-55,-54,-58,-57,-59,-60,-61,-63,-67,-69,-71,-68,-64
DATA 1924,7,9,14,35,10,161
DATA 3,3,-1,-2,-3,-2,-2,0,6,7,8,5,3,1,5,8
DATA 1924,7,9,14,55,20,162
DATA 16,15,13,11,9,12,14,19,19,18,17,14,12,12,15,23
DATA 1924,7,10,10,5,11,163
DATA 143,143,147,150,152,150,153,158,159,161,162,162,160,162,166,172
DATA 1924,7,10,11,20,10,164
DATA -8,-6,-7,-7,-10,-12,-10,-11,-11,-6,-6,-10,-13,-14,-13,-7
DATA 1924,7,10,20,16,30,165
DATA -160,-166,-170,-178,-180,-182,-183,-181,-178,-184,-195,-203,-209,-211,-203,-191
DATA 1924,7,10,17,40,9,166
REM minor addition errors cols. 1-4,8,9 corrected
DATA -27,-26,-28,-29,-33,-32,-36,-33,-32,-35,-37,-41,-47,-49,-47,-40
DATA 1924,7,22,17,0,20,167
DATA 60,69,70,68,65,63,63,64,63,66,65,64,64,64,64,70
DATA 1924,7,23,9,40,10,168
DATA 6,4,-5,-11,-18,-23,-22,-20,-19,-17,-17,-16,-1,3,4,7
DATA 1924,7,23,14,25,10,169
DATA 25,23,17,14,9,8,12,16,22,26,33,38,39,36,34,32
DATA 1924,7,23,17,10,11,170
DATA 10,10,11,11,11,10,11,12,17,22,23,23,24,24,26,27
DATA 1924,7,24,9,0,10,171
DATA -14,-15,-21,-22,-22,-19,-16,-13,-15,-15,-17,-18,-18,-18,-14,-13
DATA 1924,7,24,14,35,10,172
DATA 7,8,8,8,10,10,13,16,17,17,18,19,21,22,25,29
DATA 1924,7,24,15,40,20,173
DATA 30,30,31,31,31,33,33,35,34,35,35,35,33,33,35,45
DATA 1924,7,24,17,0,20,174
DATA 1924,7,24,17,0,20,174
DATA 96,96,90,81,75,70,68,68,75,82,81,80,81,86,94,106
DATA 1924,7,24,23,40,10,175
DATA 3,8,10,10,9,8,8,8,8,8,8,7,7,7,7,9
DATA 1924,7,25,10,0,10,176
DATA 54,54,54,55,56,56,57,58,58,58,58,60,60,60,60,64
DATA 1924,7,26,3,40,27,177
REM addition errors cols. 2,4,7 corrected

DATA 142,149,151,152,151,155,169,176,181,185,189,189,190,198,212,222
DATA 1924,7,26,4,30,29,178
DATA 71,73,73,70,69,74,80,90,102,104,106,107,110,114,130,146
DATA 1924,7,26,9,30,12,179
REM minor addition errors cols. 1,3,14 corrected
DATA 72,71,65,62,60,55,58,65,68,72,71,69,64,64,67,76

DATA 0,0,0,0,0,0,0

(continued) Here are emails three through five.

July 15, 2013:

Hi Pierre,

Each long data line has 16 entries; these are the fringe shifts (in tenths of a wavelength) recorded by Miller. Above each of these lines, is a short line giving the time of the observation. The first number is the year, the second is the month, the third is the day, the fourth is the hour Eastern Standard Time (add 5 hour to get Greenwich Mean Time) and the fifth is the minute. I think these times, for these data, refer to the beginning of the experiment, but since each turn required only about one minute, it would be good enough, to add one half as many minutes as turns (the sixth number is the number of turns of the interferometer). An error of ten minutes would be only about five arcminutes in the Lunar position. Knowing the time, you could of course then find the Lunar positions from the JPL online ephemeris, or from old almanacs.

- Joe Keller


July 15, 2013:

Hi James,

In 2004 I decided to work on Miller's Cleveland data because Miller himself had analyzed the Mt. Wilson data (Miller also made some analysis of the Cleveland data but it seems, from the notebooks, to have been very approximate, usually merely graphical, and incomplete). The Cleveland data are much shorter. If I analyzed them, then between Miller and myself, all of them would be analyzed and Cleveland could be compared to Mt. Wilson, showing that the ether drift is, at least approximately and on the average, independent of time on a scale of a few years, and independent of geographic location. Analyzing Mt. Wilson not only would have required much more data typing by me, but would have been basically a repeat of what Miller already had done by the old-fashioned but valid data processing methods of the 1920s. On the other hand, if I analyzed Cleveland and got the same result Miller did for Mt. Wilson, the statistical significance of the result would be the immediate implication. Shankland's laughable contention that the result had something to do with one corner of the room being warmer, or something to do with anything about the labs, which were totally different in Cleveland and Mt. Wilson, would be shown yet again for the absurdity that it is.

The data sheets are just tricky enough that it is impossible to have someone who does not understand the experiments, to be entering the data. Especially in these early 1922-1924 data, there are variations in format, for example which row is the non-detrended summed columns, and which are sums of + or sums of - or Miller's approximate detrended sums? There were a possibly significant number of column summation errors. One page even was missing one of its 16 columns. Many pages were inapplicable because they were Miller's side experiments designed to find out just how much an uneven heating of the room, or various schemes for shielding the interferometer, would affect the result. Some pages were cut off and I had to deduce the time and date by comparing with consecutive pages. A robot can't do it. Someone knowledgeable had to scrutinize it page by page and make every data entry judiciously. It had to be "custom made" work, not "mass production" work.

This might actually be my finished results. I've somewhat augmented the data now, by adding in the April 1927 Cleveland experiments, but adding them into the data pool didn't change the outcome much.

Over the years, I've wasted so much time submitting things to the mainstream journals only to be told by the editor or even by some anonymous office boy, that he wasn't even going to send it for peer review. So they're not really peer reviewed journals, because a few "peers" might get to see what is published, but the "peers" don't even get to see what the editor dictatorially rejects. So, since to my knowledge there are no hardcopy alternative journals to which any university library subscribes, electronic publication on alternative websites, whether or not they call themselves journals, is all there is going to be.

If you would like to publish any or all of these emails on your Orgone Research website, please be my guest! That may well be the only publication that there is, besides my posting them to the messageboard of www.metaresearch.org (website of the late Dr. Van Flandern) which is the de facto journal in which I publish all my work.

- Joe Keller


July 15, 2013:

Dear Thomas, Pierre, James,

In 2004 I didn't realize that detrending was important and it was Thomas Goodey then who insisted that it was, thereby averting disaster. The importance of detrending can be seen, for example by looking up in a table of integrals, the integral of x * sin(2*x) from -pi to pi and seeing that it is nonzero (because both factors are "odd" functions). So, thanks Thomas! Another way to recognize this truth is to recall that Fourier analysis applies only to periodic functions, not linear ones.

I augmented my data by including the April 1927 Cleveland data. This comprised an additional 20 sets for a total now of 64+20=84 sets, though the increment in turns was more, because these April 1927 sets almost always had 20 turns, whereas the 1922-1924 sets averaged less than 15 turns.

Again I searched the northern hemisphere of the celestial sphere on the coarse 5x5 degree grid (with appropriately larger right ascension increments at high declinations). This time I then refined the result by searching on a 1x1 degree box centered at the best coarse value and extending to the surrounding coarse grid points. The largest positive correlation coefficient was +0.27705 for Right Ascension 208, Declination +74 (or equivalently RA 28, Decl -74). Because longitude lines are so close together at high latitude, this is only a few degrees from the direction Miller found from the Mt. Wilson data. Making the usual normal approximation, and recalling that for the correlation coefficient, n = 2*84 = 168 now, because of independent sine and cosine terms, this is significant at sigma = 3.65. Also, it implies an apparent ether drift speed of 11.82 km/sec, not much different from the speeds Miller found at Mt. Wilson, or from what he found in Cleveland using more rudimentary analyses.

However, the largest correlation coefficient in absolute value, was a negative correlation, -0.36205 for RA 47, Decl 14 (or equivalently RA 227, Decl -14). This is significant at sigma = -4.87 ( p = 5 * 10^(-7) one-tailed) which is hugely more significant than sigma = 3.65 ( p = 1.3 * 10^(-4) one-tailed) and more significant even than the largest absolute correlation found with the 1922-1924 data alone, -4.74 (on the original coarse grid, but with the augmented data I found -4.86 even on that same coarse grid). The implied apparent ether drift speed is 11.06 km/sec.

The location, RA 227, Decl -14, lies on the ecliptic near the center of the constellation Libra. In the 1990s, the Cornell Univ. astronomy group, in an article discussing what even mainstream astronomers have dubbed in journal titles to be "the other ether drift", i.e. the "Cosmic" Microwave Background dipole, published a graph showing that the redshifts of the seemingly most distant galaxies imply that relative to them we have on average almost the same speed and direction as our apparent Cosmic Microwave Background motion, which is toward a point south of Leo. The graph shows that if progressively nearer galaxies are studied, the Sun's apparent motion relative to these, smoothly changes until, for the nearest statistically meaningful subset of galaxies (the Virgo Cluster) this motion equals the well-known "Virgo Infall" [correction by JK July 16: the Sun's apparent motion equals the Virgo Infall plus the Sun's apparent galactic orbital motion; the Virgo Infall itself is a motion of the Milky Way toward Virgo at about 300 km/sec, superimposed on the uniform Hubble recession.]. It is plausible that the direction of Miller's ether drift, apparently toward Libra, is relative to the ether immediately at hand, while the Virgo Infall amounts to the direction relative to the ether of the nearest large galaxy cluster and the apparent motion implied by the CMB dipole gives the direction relative to the ether at infinity. From Libra to Virgo to Leo is a short, smooth curve.

It is suggestive, that the best positive-correlation direction, and best absolute-correlation direction, differ by 91 (or 89) degrees. One can confirm using elementary mathematics, that if the true motion is toward (using round numbers) RA 180, Decl 0, and the number of waves along the telescope arm aimed in this direction were to decrease rather than increase (i.e., negative correlation, opposite of the change assumed by Maxwell, Michelson, Miller) then there will as a byproduct be a positive (cos(theta))^2 correlation of the number of waves in the telescope arm, with the aiming of the telescope arm in the direction of the ecliptic pole. Specifically, let's consider latitude 41deg N (i.e. Cleveland) at sidereal times 0h, 6h, 12h, 18h, using 23deg as Earth's obliquity. By trigonometry (and a little spherical trigonometry) one sees that in units of (v/c)^2/2*(number of waves), the actual effect on the difference in number of waves between telescope arm and cross arm [with the telescope arm pointed north - JK] is

-0.4304, 1, -0.4304, 1

while the expected effect assuming the Maxwell theory and a drift toward the ecliptic pole, is

0.3300, 0.9045, 0.3300, 0.1922

and the correlation coefficient of these two series, is +0.5377. That is, if the experiments are evenly distributed in sidereal time, then the true, negative correlation coefficient should result in a byproduct positive correlation coefficient that is about 0.54 times as large, and somewhat reassuringly we find indeed that 0.277/0.362 = 0.765.

- Joe Keller

Dear Pierre, James, Thomas,

The Hicks first order effect has, of course, an amplitude and a phase. The amplitude isn't directly known for Cleveland 1922-1924 (or for Mt. Wilson) because the amplitude of the Hicks effect is proportional to the number of fringes in view (that is, the expected Hicks effect is found in units of length; Miller recorded in units of fringes, so unless fringes can be converted to length, the observed amplitude of the Hicks first order effect isn't known).

Miller did record the number of fringes (e.g. typically "6" or "10", small integers, but good enough for quantitative results) for the 1927-1929 Cleveland data. So the Hicks first order effect can be assessed for Cleveland 1927-1929 and used to corroborate the Maxwell second order effect.

I've already used the Hicks first order effect to corroborate my previous results, by considering only the observed and predicted phase of the effect, not its amplitude, for Cleveland 1922-1924 (excluding the heat lamp, etc., experiments which Miller knew would have to be discarded) plus Cleveland Apr 1927 (altogether the 84 sets I referred to previously, n=84 because only one datum, phase, arises per set). I found that the largest Hicks effect is for a drift line in space toward roughly RA 200, Decl +20 (or the opposite of this), i.e. about 30 degrees different from the second order effect (the one with large negative correlation coefficient, in line with Libra) and is significant (sum of cosines of angles between observed and expected phase) at sigma = 2.7.


Years ago I looked at the lengthy calculations in Hicks' paper, and wasn't able to digest it in the time then available. Miller says in his notes that Lorentz didn't understand the Hicks effect either, when Lorentz visited Miller and they talked about it, so I'm in good company. My best guess is that it is basically a matter of the photons hitting downstream or upstream when the telescope arm is crossways of the drift, that is, the whole shebang, fringes and all, is moved by the drift in a first order way (first order in theta, but second order in v/c) that has nothing to do with interference.


I gather that if phi is the drift azimuth and theta is the telescope azimuth, then the Hicks effect is proportional to sin(phi - theta). I find that this constant of proportionality is negative if the drift is toward Libra, and of course necessarily positive if the drift is in the opposite direction.


- Joe Keller

Progress on Dayton Miller Cleveland Data


I've now inputted all of Dayton Miller's Cleveland data from the steel interferometer. These span the years 1905, 1922-1924, and 1927-1929. Searching the entire celestial sphere, the largest correlation coefficient between observed and expected second harmonic coefficients for the fringe shift, now is +0.39919, which is found for a drift parallel or antiparallel to the direction RA 208, Decl +71. Sigma for this correlation coefficient is approximately 6.9068 for one-tailed p = 2.5/10^12.

The negative correlation coefficient largest in magnitude occurs for a drift parallel or antiparallel to RA 49, Decl 18 (separated from the other axis by 90 deg). This correlation coefficient is -0.30903 for sigma = -5.2038, one-tailed p = 9/10^8: almost 40,000 times larger than p for the largest positive correlation. So it is the negative correlation which is the mathematical byproduct (the normal to the interferometer is limited to a cone and cannot range over the entire celestial sphere) and Miller's Mt. Wilson ether drift direction is confirmed by my analysis of Miller's Cleveland steel interferometer data.

These searches always are on a 5x5 deg coarse grid (with appropriately larger RA steps near the celestial poles) and then a 1x1 deg fine grid centered on the best coarse grid point and just small enough not to overlap the other coarse points. The number of experiments (sets of turns) is 135 (usually of 20 turns each, so the data set is almost half the size of the Mt. Wilson data set). The number of items correlated is 135*2 = 270, because there are sine and cosine harmonic terms.

All the 1927-1929 sets and some of the others, tell the number of fringes in view. So a phase and amplitude are likewise discoverable for the Hicks full-period effect. I haven't had time to program that yet, but the phase-only analysis somewhat confirms the above.